###################################################################### 
#
#  $HOME/.cshrc file 
#
#	$Revision: 1.4 $
#	$Date: 1998/09/30 12:14:55 $ 
#
###################################################################### 

if ( -x /usr/bin/arch )		set machine=`/usr/bin/arch`          # SunOS
if ( -x /usr/ucb/arch )		set machine=`/bin/uname -r`          # Solaris
if ( -x /usr/bsd )		set machine=`/usr/bin/uname -s`      # SGI
if ( -f /stand/vmunix )		set machine=`/bin/uname -r`          # HP
if ( -d /usr/sony )		set machine=`/usr/bin/uname -r`  # NEWS

umask 022

limit coredumpsize 0

# set defaut path 
set path = (/bin /usr/local/{bin,etc,mh} /usr/local/{gnu,tex,netscape}/bin)

switch( $machine )

# for Solaris 2.x
case 5.*:
    set path = ( \
        /usr/local/SparCompiler/bin \
        /usr/{ucb,bin,sbin,etc} \
        $path \
        /usr/{ccs,dt}/bin \
        /usr/local/bin/Wnn4 \
        /usr/local/{X11R6,java}/bin \
        /usr/openwin/bin \
        /sbin \
        /usr/sbin \
        $HOME/bin \
        )

    setenv LM_LICENSE_FILE /usr/local/flexlm/licenses/license.dat
    setenv MANPATH /usr/man:/usr/local/man:/usr/local/X11R6/man:/usr/local/gnu/man:/usr/local/tex/man:/usr/local/SparCompiler/man

breaksw

# for SGI irix
case IRIX*:

    set path = ( \
        /usr/{sbin,bsd} \
        $path \
        /usr/bin/X11 \
        /usr/local/X11R6/bin \
        $HOME/bin       \
        )

    setenv MANPATH /usr/share/catman:/usr/share/man:/usr/catman:/usr/man:/usr/local/man:/usr/local/X11R6/man:/usr/local/gnu/man:/usr/local/tex/man

    # deny messages 
    if ($?prompt ) then
        mesg -n
    endif

breaksw

# for HP HP-UX 11.00
case B.11.00:

    # set defaut path
    set path=($path /usr/bin /usr/ccs/bin /usr/contrib/bin)

    # set site path
    set path=( \
        /usr/sbin \
        /usr/bin/X11 \
        /usr/local/bin \
        /etc \
        $path \
        )

    # default MANPATH
    setenv MANPATH /usr/share/man:/usr/contrib/man:/usr/local/man

    if ( -r /etc/MANPATH ) then
       setenv MANPATH `cat /etc/MANPATH`
    endif

breaksw

case 6.1.1:
case 6.1.2:
        set path = ( \
                /usr/{sbin,bin,ucb,etc} \
                /usr/sony/bin   \
                /usr/ccs/bin    \
                /bin /sbin /etc \
                /usr/bin/{X11,mh} \
                /usr/local/bin \
                /usr/local/gnu/bin      \
                . )
        setenv  MANPATH /usr/share/man:/usr/local/man:/usr/local/gnu/man
        set filec
breaksw
endsw

# skip remaining setup if not an interactive shell
if ($?USER == 0 || $?prompt == 0) exit

# settings  for interactive shells

# set this for all shells
set ignoreeof
set filec
set hostname =  `hostname`
set history = 100
set savehist = 50
set prompt="`hostname`{`whoami`}\!: "

# aliases for all shells
#alias cd	'cd \!*;echo $cwd'
#alias cp	'cp -i'
#alias mv	'mv -i'
#alias rm	'rm -i'
#alias ls	'ls -F'

#
# u-aizu local setting
# 
setenv	NNTPSERVER	nh1		# news server
setenv	LESSCHARSET	japanese-euc

if ( -x /usr/local/bin/select_jserver ) then	# Kana Kanji server
    setenv JSERVER `select_jserver`
endif

# setenv JSERVER You_selected_jserver
# setenv JSERVER localhost

# limit cputime 24h
# limit filesize 5m

